# Maintainer: artoo <artoo@artixlinux.org>
# Maintainer: nous <nous@artixlinux.org>

pkgbase=desktop-presets
#pkgbase=artix-${_pkgbase}
pkgname=('artix-common-presets' 'artix-mate-presets' 'artix-lxqt-presets' 'artix-lxde-presets')
pkgver=0.8+16+gac1c8c1
pkgrel=1
pkgdesc='Artix graphical ISO presets'
arch=('any')
groups=(${pkgbase})
url="https://gitea.artixlinux.org/artix/desktop-presets"
license=('GPL')
depends=('artix-dark-theme' 'artix-common-presets')
conflicts=('desktop-presets')
makedepends=('git')
_commit=ac1c8c1edb95d26953966386177d9d815d1b16b8
source=("git+$url.git#commit=${_commit}")
sha256sums=('SKIP')

pkgver() {
    cd ${pkgbase}
    git describe --tags | sed 's/-/+/g'
}

_inst_dir(){
    cd ${pkgbase} #-${pkgver}
    local profile="$1"
    if [[ -d $profile/skel ]];then
        install -d ${pkgdir}/etc
        cp -vr $profile/skel ${pkgdir}/etc
    fi
    if [[ -d $profile/schemas ]];then
        install -d ${pkgdir}/usr/share/glib-2.0
        cp -vr $profile/schemas ${pkgdir}/usr/share/glib-2.0
    fi
    if [[ -d $profile/dconf ]];then
        install -d ${pkgdir}/etc
        cp -vr $profile/dconf ${pkgdir}/etc
    fi
    if [[ -d $profile/scripts ]];then
        install -d ${pkgdir}/usr/bin
        cp -v $profile/scripts/* ${pkgdir}/usr/bin
    fi
}

package_artix-common-presets() {
pkgdesc='Artix ISO presets, common files'
    _inst_dir 'common'
}

package_artix-mate-presets() {
pkgdesc='Artix MATE ISO presets'
provides=('desktop-presets')
    _inst_dir 'mate'
}

package_artix-lxqt-presets() {
pkgdesc='Artix LXQt ISO presets'
provides=('desktop-presets')
    _inst_dir 'lxqt'
}

package_artix-lxde-presets() {
pkgdesc='Artix LXDE ISO presets'
provides=('desktop-presets')
    _inst_dir 'lxde'
}